Add autograder-py

arch/autograder-py/PKGBUILD

@@ -0,0 +1,45 @@
+# Maintainer: Alexander Rosenberg <zanderpkg at pm dot me>
+
+pkgname=autograder-py
+pkgver=0.6.15
+pkgrel=1
+pkgdesc="The Python interface to the autograder"
+url="https://github.com/edulinq/autograder-py"
+license=('MIT')
+arch=('any')
+depends=(
+  'python'
+  'python-argon2-cffi'
+  'python-flake8'
+  'python-gitpython'
+  'python-platformdirs'
+  'python-requests'
+)
+makedepends=(
+  'python-build'
+  'python-packaging'
+  'python-requests-toolbelt'
+  'twine'
+  'python-vermin'
+)
+
+source=(
+  "$pkgname-$pkgver.tar.gz::$url/archive/refs/tags/v$pkgver.tar.gz"
+)
+
+sha256sums=('433c0ef6a9200f0e011385d9fc8df471f10950b6e4f4a52d3bb0f97d2dd66c60')
+
+build() {
+  cd "$pkgname-$pkgver"
+  python -m build --wheel --no-isolation --skip-dependency-check
+}
+
+check() {
+  "$pkgname-$pkgver/run_tests.py"
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+  python -I -m installer --destdir="${pkgdir}" dist/*.whl
+  install -Dm644 LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
+}