Implement bind command

This command allows binding compsitor commands to keys

src/Control.zig

@@ -110,9 +110,12 @@ fn runCommand(
     var failure_message: []const u8 = undefined;
     command.run(allocator, seat, args.items, &failure_message) catch |err| {
         if (err == command.Error.CommandFailed) {
-            const out = std.cstr.addNullByte(allocator, failure_message) catch "out of memory";
+            defer allocator.free(failure_message);
+            const out = std.cstr.addNullByte(allocator, failure_message) catch {
+                c.zriver_command_callback_v1_send_failure(callback_resource, "out of memory");
+                return;
+            };
             defer allocator.free(out);
-            allocator.free(failure_message);
             c.zriver_command_callback_v1_send_failure(callback_resource, out);
         } else {
             c.zriver_command_callback_v1_send_failure(

src/command.zig

@@ -27,6 +27,7 @@ const impl = struct {
     const focus = @import("command/focus.zig").focus;
     const focusAllTags = @import("command/focus_all_tags.zig").focusAllTags;
     const focusOutput = @import("command/focus_output.zig").focusOutput;
+    const bind = @import("command/bind.zig").bind;
     const focusTag = @import("command/focus_tag.zig").focusTag;
     const layout = @import("command/layout.zig").layout;
     const modMasterCount = @import("command/mod_master_count.zig").modMasterCount;
@@ -76,6 +77,7 @@ const str_to_impl_fn = [_]Definition{
     .{ .name = "mod_master_factor", .impl = impl.modMasterFactor },
     .{ .name = "send_to_output",    .impl = impl.sendToOutput },
     .{ .name = "spawn",             .impl = impl.spawn },
+    .{ .name = "bind",              .impl = impl.bind },
     .{ .name = "tag_view",          .impl = impl.tagView },
     .{ .name = "tag_view_all_tags", .impl = impl.tagViewAllTags },
     .{ .name = "toggle_float",      .impl = impl.toggleFloat },

src/command/bind.zig

@@ -0,0 +1,109 @@
+// This file is part of river, a dynamic tiling wayland compositor.
+//
+// Copyright 2020 Isaac Freund
+//
+// This program is free software: you can redistribute it and/or modify
+// it under the terms of the GNU General Public License as published by
+// the Free Software Foundation, either version 3 of the License, or
+// (at your option) any later version.
+//
+// This program is distributed in the hope that it will be useful,
+// but WITHOUT ANY WARRANTY; without even the implied warranty of
+// MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+// GNU General Public License for more details.
+//
+// You should have received a copy of the GNU General Public License
+// along with this program. If not, see <https://www.gnu.org/licenses/>.
+
+const std = @import("std");
+
+const c = @import("../c.zig");
+
+const Error = @import("../command.zig").Error;
+const Keybind = @import("../Keybind.zig");
+const Seat = @import("../Seat.zig");
+
+const modifier_names = [_]struct {
+    name: []const u8,
+    modifier: u32,
+}{
+    .{ .name = "Shift", .modifier = c.WLR_MODIFIER_SHIFT },
+    .{ .name = "Lock", .modifier = c.WLR_MODIFIER_CAPS },
+    .{ .name = "Control", .modifier = c.WLR_MODIFIER_CTRL },
+    .{ .name = "Mod1", .modifier = c.WLR_MODIFIER_ALT },
+    .{ .name = "Mod2", .modifier = c.WLR_MODIFIER_MOD2 },
+    .{ .name = "Mod3", .modifier = c.WLR_MODIFIER_MOD3 },
+    .{ .name = "Mod4", .modifier = c.WLR_MODIFIER_LOGO },
+    .{ .name = "Mod5", .modifier = c.WLR_MODIFIER_MOD5 },
+};
+
+/// Create a new keybind for a given mode
+///
+/// bind normal Control|Shift|Mod4 Comma spawn alacritty
+pub fn bind(
+    allocator: *std.mem.Allocator,
+    seat: *Seat,
+    args: []const []const u8,
+    failure_message: *[]const u8,
+) Error!void {
+    if (args.len < 4) return Error.NotEnoughArguments;
+
+    // Parse the mode
+    const config = seat.input_manager.server.config;
+    const target_mode = args[1];
+    const mode_id = config.mode_to_id.getValue(target_mode) orelse {
+        failure_message.* = try std.fmt.allocPrint(
+            allocator,
+            "cannot add keybind to non-existant mode '{}'",
+            .{target_mode},
+        );
+        return Error.CommandFailed;
+    };
+
+    // Parse the modifiers
+    var it = std.mem.split(args[2], "|");
+    var modifiers: u32 = 0;
+    while (it.next()) |mod_name| {
+        for (modifier_names) |def| {
+            if (std.mem.eql(u8, def.name, mod_name)) {
+                modifiers |= def.modifier;
+                break;
+            }
+        } else {
+            failure_message.* = try std.fmt.allocPrint(
+                allocator,
+                "invalid modifier '{}'",
+                .{mod_name},
+            );
+            return Error.CommandFailed;
+        }
+    }
+
+    // Parse the keysym
+    const keysym_name = try std.cstr.addNullByte(allocator, args[3]);
+    defer allocator.free(keysym_name);
+    const keysym = c.xkb_keysym_from_name(keysym_name, .XKB_KEYSYM_CASE_INSENSITIVE);
+    if (keysym == c.XKB_KEY_NoSymbol) {
+        failure_message.* = try std.fmt.allocPrint(
+            allocator,
+            "invalid keysym '{}'",
+            .{args[3]},
+        );
+        return Error.CommandFailed;
+    }
+
+    // Check if the mapping already exists
+    const mode_mappings = &config.modes.items[mode_id];
+    for (mode_mappings.items) |existant_mapping| {
+        if (existant_mapping.modifiers == modifiers and existant_mapping.keysym == keysym) {
+            failure_message.* = try std.fmt.allocPrint(
+                allocator,
+                "a mapping for modifiers '{}' and keysym '{}' already exists",
+                .{ args[2], args[3] },
+            );
+            return Error.CommandFailed;
+        }
+    }
+
+    try mode_mappings.append(try Keybind.init(allocator, keysym, modifiers, args[4..]));
+}