river/src/command.zig

const std = @import("std");
const c = @import("c.zig");

const Log = @import("log.zig").Log;
const Server = @import("server.zig").Server;
const ViewStack = @import("view_stack.zig").ViewStack;

pub const Arg = union {
    int: i32,
    uint: u32,
    float: f64,
    str: []const u8,
    none: void,
};

pub const Command = fn (server: *Server, arg: Arg) void;

/// Exit the compositor, terminating the wayland session.
pub fn exitCompositor(server: *Server, arg: Arg) void {
    c.wl_display_terminate(server.wl_display);
}

/// Shift focus to the next visible view, wrapping if needed.
pub fn focusNextView(server: *Server, arg: Arg) void {
    server.root.focusNextView();
}

/// Shift focus to the previous visible view, wrapping if needed.
pub fn focusPrevView(server: *Server, arg: Arg) void {
    server.root.focusPrevView();
}

/// Modify the number of master views
pub fn modifyMasterCount(server: *Server, arg: Arg) void {
    const delta = arg.int;
    const output = server.root.focusedOutput();
    output.master_count = @intCast(
        u32,
        std.math.max(0, @intCast(i32, output.master_count) + delta),
    );
    server.root.arrange();
}

/// Modify the percent of the width of the screen that the master views occupy.
pub fn modifyMasterFactor(server: *Server, arg: Arg) void {
    const delta = arg.float;
    const output = server.root.focusedOutput();
    const new_master_factor = std.math.min(
        std.math.max(output.master_factor + delta, 0.05),
        0.95,
    );
    if (new_master_factor != output.master_factor) {
        output.master_factor = new_master_factor;
        server.root.arrange();
    }
}

/// Bump the focused view to the top of the stack.
/// TODO: if the top of the stack is focused, bump the next visible view.
pub fn zoom(server: *Server, arg: Arg) void {
    if (server.root.focused_view) |current_focus| {
        const output = server.root.focusedOutput();
        const node = @fieldParentPtr(ViewStack.Node, "view", current_focus);
        if (node != output.views.first) {
            output.views.remove(node);
            output.views.push(node);
            server.root.arrange();
        }
    }
}

/// Switch focus to the passed tags.
pub fn focusTags(server: *Server, arg: Arg) void {
    const tags = arg.uint;
    const output = server.root.focusedOutput();
    output.pending_focused_tags = tags;
    server.root.arrange();
}

/// Toggle focus of the passsed tags.
pub fn toggleTags(server: *Server, arg: Arg) void {
    const tags = arg.uint;
    const output = server.root.focusedOutput();
    const new_focused_tags = output.current_focused_tags ^ tags;
    if (new_focused_tags != 0) {
        output.pending_focused_tags = new_focused_tags;
        server.root.arrange();
    }
}

/// Set the tags of the focused view.
pub fn setFocusedViewTags(server: *Server, arg: Arg) void {
    const tags = arg.uint;
    if (server.root.focused_view) |view| {
        if (view.current_tags != tags) {
            view.pending_tags = tags;
            server.root.arrange();
        }
    }
}

/// Toggle the passed tags of the focused view
pub fn toggleFocusedViewTags(server: *Server, arg: Arg) void {
    const tags = arg.uint;
    if (server.root.focused_view) |view| {
        const new_tags = view.current_tags ^ tags;
        if (new_tags != 0) {
            view.pending_tags = new_tags;
            server.root.arrange();
        }
    }
}

/// Spawn a program.
/// TODO: make this take a program as a paramter and spawn that
pub fn spawn(server: *Server, arg: Arg) void {
    const cmd = arg.str;

    const argv = [_][]const u8{ "/bin/sh", "-c", cmd };
    const child = std.ChildProcess.init(&argv, std.heap.c_allocator) catch |err| {
        Log.Error.log("Failed to execute {}: {}", .{ cmd, err });
        return;
    };
    std.ChildProcess.spawn(child) catch |err| {
        Log.Error.log("Failed to execute {}: {}", .{ cmd, err });
        return;
    };
}

/// Close the focused view, if any.
pub fn close(server: *Server, arg: Arg) void {
    if (server.root.focused_view) |view| {
        view.close();
    }
}