# Maintainer: Alexander Rosenberg <zanderpkg at pm dot me>

pkgname=dwmblocks
pkgver=1
pkgrel=1
pkgdesc='Modular status bar for dwm'
url='https://git.zander.im/Zander671/dwmblocks/'
arch=('x86_64')
license=('custom:ISC')
depends=('libx11')
optdepends=('pulseaudio: for dwmblocks-pulse-listener'
            'pamixer: for dwmblocks-volume'
            'networkmanager: for dwmblocks-network internet'
            'bluez-utils: for dwmblocks-network bluetooth')
DLAGENTS=('tar::/bin/sh -c echo\ %u\ |\ cut\ -c7-\ |\ head\ -c-5\ |\ xargs\ -Isrc\ -n\ 1\ tar\ -cf\ %o\ src')
source=('dwmblocks.c'
        'pulse-listener.c'
        'pulse-listener.h'
        'LICENSE'
        'README.md'
        'Makefile'
        'blocks.h'
        'tar://scripts.tar')
sha256sums=('SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP'
            'SKIP')

_no_x=1

build() {
    cp blocks.h blocks.def.h
    make NO_X=$_no_x
}

package() {
    make DESTDIR="$pkgdir" PREFIX='/usr' install
    install -m 0644 -Dt "$pkgdir/usr/share/doc/dwmblocks" 'README.md'
    install -m 0644 -Dt "$pkgdir/usr/share/licenses/dwmblocks" 'LICENSE'
}