# Maintainer: Alexander Rosenberg <zanderpkg at pm dot me>

pkgname=libexword-re
pkgver=96
pkgrel=1
pkgdesc='A more friendly fork of libexword, a library for transfering files over USB to casio EX-word electronic dictionaries'
url='https://github.com/CaesarW/libexword-re.git'
arch=('x86_64')
license=('GPL3')
depends=('libusb' 'readline' 'glib2')
makedepends=('cmake' 'libtool' 'git' 'make')
source=('git+https://github.com/CaesarW/libexword-re.git'
        '40-exword.rules')
sha256sums=('SKIP'
            '6d81bb6836b00ac0e31813a540490e776fa2133d6932e70307c0eec140ce56ae')

pkgver(){
  cd "$pkgname"
  git rev-list --count HEAD
}

build() {
  cd "$pkgname"
  cmake -B build -S src
  make -C build
}

package() {
  cd "$pkgname"
  install -m755 -D build/exword "$pkgdir/usr/bin/exword"
  install -m644 -D ../40-exword.rules "$pkgdir/etc/udev/rules.d/40-exword.rules"
  install -m644 -D README.md "$pkgdir/usr/share/doc/$pkgname/README"
  install -m644 -D docs/models.md "$pkgdir/usr/share/doc/$pkgname/models.md"
  install -m644 -D docs/protocol.md "$pkgdir/usr/share/doc/$pkgname/protocol.md"
}